Inventor Labs: Technology/INVENTORLABS_TECHNOLOGY.BIN/mac/FILES/SHARED.CST/00501_Script_pano movie handlers

Text File | 1997-07-24 | 3KB | 74 lines

-- SetPanoNode
--      pNodeID is the number of the node to go to
--      pUpdate is true if a screen update is to be performed
--      [pQuality] is the quality level at which to display the update
--
-- Changes the current node as specified.  If pUpdate is true, updates the
-- screen to reflect that node's default view.  Has the side effect of changing
-- the current quality level to pQuality, if specified.
-------------------------------------------------------------------------------
on SetPanoNode pNodeID, pUpdate, pQuality
  global gQTVRInstance
  if IsQTVRMovie(gQTVRInstance) then
    QTVRSetNodeID(gQTVRInstance, integer(pNodeID))
    if not voidP(pQuality) then QTVRSetQuality(gQTVRInstance, pQuality)
    if pUpdate then QTVRUpdate(gQTVRInstance)
  end if
end


--=============================================================================
-- SwingPanoMovie
--      pHPan is the destination horizontal pan angle
--      pVPan is the destination vertical pan angle
--      pZoom is the destination zoom angle
--      pSwingSpeed is the speed at which to swing
--      pSwingQuality is the quality at which to swing
--      pFinalQuality is the quality at which to re-update the destination view
--
-- Swings the view around to a specified direction.  Has the side effect of
-- changing the current quality level to pFinalQuality
-------------------------------------------------------------------------------
on SwingPanoMovie pHPan, pVPan, pZoom, pSwingSpeed, pSwingQuality, pFinalQuality
  global gQTVRInstance
  if IsQTVRMovie(gQTVRInstance) then
    -- Set up the destination pan and zoom angles
    QTVRSetFOV(gQTVRInstance,pZoom)
    QTVRSetTiltAngle(gQTVRInstance,pVPan)
    QTVRSetPanAngle(gQTVRInstance,pHPan)

    -- For performance, you can use lower quality during the swing
    QTVRSetQuality(gQTVRInstance, pSwingQuality)
    QTVRSetTransitionMode(gQTVRInstance, "swing")
    QTVRSetTransitionSpeed(gQTVRInstance, pSwingSpeed)
    QTVRUpdate(gQTVRInstance)

    -- Set transition mode to normal
    QTVRSetTransitionMode(gQTVRInstance, "normal")

    -- Only do a reupdate if the quality values are different
    if pFinalQuality <> pSwingQuality then
      QTVRSetQuality(gQTVRInstance, pFinalQuality)
      QTVRUpdate(gQTVRInstance)
    end if
  end if
end


--=============================================================================
-- CollapsePanoMovie
--
-- Collapses to the currently selected hot spot.
-- Mac only
-------------------------------------------------------------------------------
on CollapsePanoMovie
  global gQTVRInstance

  -- Make sure we're on a mac before trying this
  if the machineType <> 256 then

    if IsQTVRMovie(gQTVRInstance) then
      QTVRCollapseToHotSpotRgn(gQTVRInstance)
    end if
  end if
end